ENH: Add new files for modular build system

CMake/CTestCustom.cmake.in

+#
+# Note that the OTB/CMakeLists.txt file configures this file
+#
+#               CMake/CTestCustom.cmake.in
+#
+# to this file
+#
+#       ${OTB_BINARY_DIR}/CTestCustom.cmake
+#
+#----------------------------------------------------------------------
+#
+# For further details regarding this file,
+# see http://www.cmake.org/Wiki/CMake_Testing_With_CTest#Customizing_CTest
+#
+# and
+# http://www.kitware.com/blog/home/post/27
+#
+#----------------------------------------------------------------------
+
+set(CTEST_CUSTOM_MAXIMUM_PASSED_TEST_OUTPUT_SIZE 1000000)
+set(CTEST_CUSTOM_MAXIMUM_NUMBER_OF_WARNINGS 300)
+set(CTEST_CUSTOM_MAXIMUM_NUMBER_OF_ERRORS 50)
+
+
+set(CTEST_CUSTOM_COVERAGE_EXCLUDE
+ ${CTEST_CUSTOM_COVERAGE_EXCLUDE}
+
+ # Exclude try_compile sources from coverage results:
+ "/CMakeFiles/CMakeTmp/"
+
+ # Exclude files from the Examples directories
+ #".*/Examples/.*"
+
+ # Exclude files from the ThirdParty Utilities directories
+ ".*/Testing/Utilities/.*"
+ ".*/Utilities/.*"
+
+ # Exclude SWIG wrappers files
+ ".*/Code/Wrappers/SWIG/otbApplicationPYTHON_wrap.*"
+ ".*/Code/Wrappers/SWIG/otbApplicationJAVA_wrap.*"
+
+ # Exclude Qt moc file
+ ".*moc_.*"
+ )
+
+set(CTEST_CUSTOM_WARNING_EXCEPTION
+  ${CTEST_CUSTOM_WARNING_EXCEPTION}
+  "vcl_deprecated_header"
+  "backward_warning"
+  "[Uu]tilities"
+  "warning LNK4221"
+  "ranlib:.*file:.*has no symbols"
+  "ranlib: file: .+ has no symbols"
+  "ranlib:.*warning for library:.*the table of contents is empty.*no object file members in the library define global symbols.*"
+  "libtool:.*file:.*has no symbols"
+  "Fl_Image.H:.*warning:.*dereferencing type-punned pointer will break strict-aliasing rules.*"
+  "warning -.: directory name .* does not exist"
+  "ld.*warning.*duplicate dylib.*"
+  "WARNING non-zero return value in ctest"
+  ".*Microsoft.*include.*.h.*[Ww]arning.*"
+  ".*gdal_priv.h.*[Ww]arning.*"
+  ".*cpl_string.h.*[Ww]arning.*"
+
+  # Ignore clang's summary warning, assuming prior text has matched some
+  # other warning expression:
+  "[0-9,]+ warnings? generated."
+
+  )

CMake/ExternalData_config.cmake.in

+set(ExternalData_OBJECT_STORES "@ExternalData_OBJECT_STORES@")
+set(ExternalData_URL_TEMPLATES "@ExternalData_URL_TEMPLATES@")
+set(ExternalData_TIMEOUT_INACTIVITY "@ExternalData_TIMEOUT_INACTIVITY@")
+set(ExternalData_TIMEOUT_ABSOLUTE "@ExternalData_TIMEOUT_ABSOLUTE@")

CMake/FindAgg.cmake

+# Find the AntiGrain Geometry graphical toolkit header files
+#
+#   AGG_FOUND        - True if AGG found.
+#   AGG_INCLUDE_DIRS - where to find agg_pixfmt_rgba.h, etc.
+#
+
+if( AGG_INCLUDE_DIR )
+    # Already in cache, be silent
+    set( AGG_FIND_QUIETLY TRUE )
+endif()
+
+find_path( AGG_INCLUDE_DIR agg_pixfmt_rgba.h
+  PATH_SUFFIXES agg2
+  )
+
+# handle the QUIETLY and REQUIRED arguments and set AGG_FOUND to TRUE if
+# all listed variables are TRUE
+include( FindPackageHandleStandardArgs )
+FIND_PACKAGE_HANDLE_STANDARD_ARGS( Agg DEFAULT_MSG AGG_INCLUDE_DIR )
+
+mark_as_advanced( AGG_INCLUDE_DIR )
+
+if(AGG_FOUND)
+  set(AGG_INCLUDE_DIRS ${AGG_INCLUDE_DIR})
+else()
+  set(AGG_INCLUDE_DIRS)
+endif()
+

CMake/FindFFTW.cmake

+## FFTW can be compiled and subsequently linked against
+## various data types.
+## There is a single set of include files, and then muttiple libraries,
+## One for each type.  I.e. libfftw.a-->double, libfftwf.a-->float
+
+## The following logic belongs in the individual package
+## mark_as_advanced(ITK_USE_FFTWD)
+## option(ITK_USE_FFTWD "Use double precision FFTW if found" ON)
+## mark_as_advanced(ITK_USE_FFTWF)
+## option(ITK_USE_FFTWF "Use single precision FFTW if found" ON)
+
+if(ITK_USE_FFTWD OR ITK_USE_FFTWF)
+
+  set(FFTW_INC_SEARCHPATH
+    /sw/include
+    /usr/include
+    /usr/local/include
+    /usr/include/fftw
+    /usr/local/include/fftw
+  )
+
+  find_path(FFTW_INCLUDE_PATH fftw3.h ${FFTW_INC_SEARCHPATH})
+
+  if(FFTW_INCLUDE_PATH)
+    set(FFTW_INCLUDE ${FFTW_INCLUDE_PATH})
+  endif()
+
+  if(FFTW_INCLUDE)
+    include_directories( ${FFTW_INCLUDE})
+  endif()
+
+  get_filename_component(FFTW_INSTALL_BASE_PATH ${FFTW_INCLUDE_PATH} PATH)
+
+  set(FFTW_LIB_SEARCHPATH
+    ${FFTW_INSTALL_BASE_PATH}/lib
+    /usr/lib/fftw
+    /usr/local/lib/fftw
+  )
+
+  if(ITK_USE_FFTWD)
+    mark_as_advanced(FFTWD_LIB)
+    find_library(FFTWD_LIB fftw3 ${FFTW_LIB_SEARCHPATH}) #Double Precision Lib
+    find_library(FFTWD_THREADS_LIB fftw3_threads ${FFTW_LIB_SEARCHPATH}) #Double Precision Lib only if compiled with threads support
+
+    if(FFTWD_LIB)
+      set(FFTWD_FOUND 1)
+      get_filename_component(FFTW_LIBDIR ${FFTWD_LIB} PATH)
+      if(FFTWD_THREADS_LIB)
+        set(FFTWD_LIB ${FFTWD_LIB} ${FFTWD_THREADS_LIB} )
+      endif()
+    endif()
+  endif()
+
+  if(ITK_USE_FFTWF)
+    mark_as_advanced(FFTWF_LIB)
+    find_library(FFTWF_LIB fftw3f ${FFTW_LIB_SEARCHPATH}) #Single Precision Lib
+    find_library(FFTWF_THREADS_LIB fftw3f_threads ${FFTW_LIB_SEARCHPATH}) #Single Precision Lib only if compiled with threads support
+
+    if(FFTWF_LIB)
+      set(FFTWF_FOUND 1)
+      get_filename_component(FFTW_LIBDIR ${FFTWF_LIB} PATH)
+      if(FFTWF_THREADS_LIB)
+        set(FFTWF_LIB ${FFTWF_LIB} ${FFTWF_THREADS_LIB} )
+      endif()
+    endif()
+  endif()
+
+endif()

CMake/FindGeoTIFF.cmake

+# - Find GEOTIFF library
+# Find the native GEOTIFF includes and library
+#
+#   GEOTIFF_FOUND        - True if GEOTIFF found.
+#   GEOTIFF_INCLUDE_DIRS - where to find geotiff.h
+#   GEOTIFF_LIBRARIES    - List of libraries to link when using GEOTIFF.
+#
+
+find_path( GEOTIFF_INCLUDE_DIR geotiff.h
+           PATH_SUFFIXES geotiff libgeotiff )
+
+set( GEOTIFF_NAMES ${GEOTIFF_NAMES} geotiff_i geotiff libgeotiff_i libgeotiff )
+find_library( GEOTIFF_LIBRARY NAMES ${GEOTIFF_NAMES} )
+
+mark_as_advanced( GEOTIFF_INCLUDE_DIR GEOTIFF_LIBRARY )
+
+# handle the QUIETLY and REQUIRED arguments and set GEOTIFF_FOUND to TRUE if 
+# all listed variables are TRUE
+include(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS( GeoTIFF DEFAULT_MSG
+                                    GEOTIFF_LIBRARY
+                                    GEOTIFF_INCLUDE_DIR)
+
+if(GEOTIFF_FOUND)
+  set( GEOTIFF_INCLUDE_DIRS ${GEOTIFF_INCLUDE_DIR} )
+  set( GEOTIFF_LIBRARIES ${GEOTIFF_LIBRARY} )
+endif()

CMake/FindICUUC.cmake

+# - Find ICUUC
+# Find the native ICUUC includes and library
+#
+#   ICUUC_FOUND        - True if ICUUC found.
+#   ICUUC_INCLUDE_DIRS - where to find unicode/unistr.h, etc.
+#   ICUUC_LIBRARIES    - List of libraries when using ICUUC.
+#
+
+if( ICUUC_INCLUDE_DIR )
+    # Already in cache, be silent
+    set( ICUUC_FIND_QUIETLY TRUE )
+endif()
+
+find_path( ICUUC_INCLUDE_DIR unicode/unistr.h )
+
+find_library( ICUUC_LIBRARY
+              NAMES icuuc )
+
+# handle the QUIETLY and REQUIRED arguments and set ICUUC_FOUND to TRUE if
+# all listed variables are TRUE
+include( FindPackageHandleStandardArgs )
+FIND_PACKAGE_HANDLE_STANDARD_ARGS( ICUUC DEFAULT_MSG ICUUC_LIBRARY ICUUC_INCLUDE_DIR )
+
+mark_as_advanced( ICUUC_INCLUDE_DIR ICUUC_LIBRARY )
+
+if(ICUUC_FOUND)
+  set(ICUUC_INCLUDE_DIRS ${ICUUC_INCLUDE_DIR})
+  set(ICUUC_LIBRARIES ${ICUUC_LIBRARY})
+else()
+  set(ICUUC_INCLUDE_DIRS)
+  set(ICUUC_LIBRARIES)
+endif()
+